Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00042_SimpleAnim.ls

Text File | 2004-07-11 | 3.0 KB | 135 lines

--
-- SimpleAnim
--

property ancestor
property simpleDelay


on new me
  -- set constants:
  set simpleDelay = 7

  -- initialize the ancestor:
  set ancestor = new (script "SpriteTools")

  return me
end


-- clear out all of my stuff

on destruct me
  -- destruct my chain
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end


-- this will animate a given sprite, based on its position in the cast
-- it only animates forward (if you wanted to animate from member 12 [in sprite 10]
-- to member 20, you would say basicSpriteAnim(gUI, 10, 8)
on basicSpriteAnim me, spr, howMany
  set oldMember = 0
  set oldPuppet = 0

  -- record everything
  set oldPuppet = the puppet of sprite spr
  set oldMember = the castNum of sprite spr

  -- puppet if we must
  if not(oldPuppet) then
    puppetSprite spr, TRUE
  end if

  -- now we animate
  repeat with x = 1 to howMany
    set the castNum of sprite spr = (oldMember + x)
    updateStage
    wait(simpleDelay)
  end repeat

  -- now we are done animating
  if oldPuppet then
    set the castNum of sprite spr = oldMember
  else
    puppetSprite spr, FALSE
  end if

  unloadCast (me)
  return 1
end


-- this will animate a given sprite, based on a position in the cast (via name)
-- it will locate member baseName, and start at basename + 1 in the cast

on basicNameAnim me, baseName, spr, howMany
  -- we will see if we have a member called baseName
  if the number of member baseName > 0 then
    -- record everything
    set oldPuppet = the puppet of sprite spr
    set oldMember = the castNum of sprite spr

    puppetSound "button noise", TRUE
    -- puppet if we must
    if not(oldPuppet) then
      puppetSprite spr, TRUE
    end if

    -- now we animate
    repeat with x = 1 to howMany
      set the member of sprite spr = (the number of member baseName) + x
      updateStage
      wait(simpleDelay)
    end repeat

    -- now we are done animating
    if oldPuppet then
      set the castNum of sprite spr = oldMember
    else
      puppetSprite spr, FALSE
    end if

    unloadCast (me)
    return 1
  else
    unloadCast (me)
    return 0
  end if
end


-- this will animate a given sprite, based on a position in the cast (via name)
-- it will locate member baseName, and start at basename + 1 in the cast
-- this version does not play a sound.

on basicNameAnimSilent me, baseName, spr, howMany
  -- we will see if we have a member called baseName
  if the number of member baseName > 0 then
    -- record everything
    set oldPuppet = the puppet of sprite spr
    set oldMember = the castNum of sprite spr

    -- now we animate
    repeat with x = 1 to howMany
      set the member of sprite spr = (the number of member baseName) + x
      updateStage
      wait(simpleDelay)
    end repeat

    -- now we are done animating
    if oldPuppet then
      set the castNum of sprite spr = oldMember
    else
      puppetSprite spr, FALSE
    end if

    unloadCast (me)
    return 1
  else
    unloadCast (me)
    return 0
  end if
end